Object 屬性

全部顯示

使用 Visual Basic 中的 Object 屬性可以返回對(duì) ActiveX 對(duì)象的引用，該對(duì)象與控件中的鏈接或嵌入的 OLE 對(duì)象相關(guān)聯(lián)。使用該引用可以訪問(wèn) OLE 對(duì)象的屬性，或者調(diào)用 OLE 對(duì)象的方法。

expression.Object

expression     必需。返回“應(yīng)用于”列表中的一個(gè)對(duì)象的表達(dá)式。

說(shuō)明

Object 屬性返回對(duì) ActiveX 對(duì)象的引用。使用 Set 語(yǔ)句可以將該 ActiveX 對(duì)象指定給某對(duì)象變量。返回的對(duì)象引用的類型取決于創(chuàng)建 OLE 對(duì)象的應(yīng)用程序。

在所有視圖中，Object 屬性設(shè)置均為只讀的。

在 Microsoft Access 窗體中嵌入或鏈接 OLE 對(duì)象時(shí)，可以設(shè)置屬性來(lái)確定對(duì)象類型和容器控件行為，但不能直接設(shè)置或讀取 OLE 對(duì)象的屬性，或是應(yīng)用它的方法，但在執(zhí)行“自動(dòng)化”時(shí)這是可以的。Object 屬性返回對(duì)某個(gè)“自動(dòng)化”對(duì)象的引用，該對(duì)象代表鏈接或嵌入的 OLE 對(duì)象。使用該引用，可以通過(guò)設(shè)置或讀取 OLE 對(duì)象的屬性或應(yīng)用它的方法來(lái)更改它。例如，Microsoft Excel 是一個(gè)支持“自動(dòng)化”的 COM 組件。如果已經(jīng)在 Microsoft Access 窗體中嵌入了 Microsoft Excel 工作表，就可以使用 Object 屬性將引用設(shè)為與該工作表關(guān)聯(lián)的 Worksheet 對(duì)象，然后就可以使用這個(gè) Worksheet 對(duì)象的所有屬性和方法。

有關(guān) ActiveX 對(duì)象支持的屬性和方法的詳細(xì)信息，請(qǐng)參閱用于創(chuàng)建 OLE 對(duì)象的應(yīng)用程序的文檔。

示例

下面的示例使用名為 OLE1 的未綁定對(duì)象框的 Object 屬性?？蛻裘Q和地址信息將插入在嵌入的 Microsoft Word 文檔中，該文檔設(shè)置為套用信函格式，名稱、地址信息和信函主體中的樣本文本都使用占位符。該過(guò)程將替換每條記錄的占位符信息，然后打印套用信函，但不保存所打印的套用信函的副本。

Sub PrintFormLetter_Click()

    Dim objWord As Object

    Dim strCustomer As String, strAddress As String

    Dim strCity As String, strRegion As String

    ' Assign object property of control to variable.

    Set objWord = Me!OLE1.Object.Application.Wordbasic

    ' Assign customer address to variables.

    strCustomer = Me!CompanyName

    strAddress = Me!Address

    strCity = Me!City & ", "

    If Not IsNull(Me!Region) Then

        strRegion = Me!Region

    Else

        strRegion = Me!Country

    End If

    ' Activate ActiveX control.

    Me!OLE1.Action = acOLEActivate

    With objWord

        .StartOfDocument

        ' Go to first placeholder.

        .LineDown 2

        ' Highlight placeholder text.

        .EndOfLine 1

        ' Insert customer name.

        .Insert strCustomer

        ' Go to next placeholder.

        .LineDown

        .StartOfLine

        ' Highlight placeholder text.

        .EndOfLine 1

        ' Insert address.

        .Insert strAddress

        ' Go to last placeholder.

        .LineDown

        .StartOfLine

        ' Highlight placeholder text.

        .EndOfLine 1

        ' Insert City and Region.

        .Insert strCity & strRegion

        .FilePrint

        .FileClose

    End With

    Set objWord = Nothing

End Sub