Lines 屬性

全部顯示

Lines 屬性返回一個(gè)字符串，該字符串包含標(biāo)準(zhǔn)模塊或類模塊中指定的一行或數(shù)行的內(nèi)容。String 型，只讀。

expression.Lines(Line, NumLines)

expression     必需。返回“應(yīng)用于”列表中的一個(gè)對(duì)象的表達(dá)式。

Line     必需 Long 型。返回第一行的行號(hào)。

NumLines     必需 Long 型。返回行數(shù)。

說明

Lines 屬性僅在使用 Visual Basic 時(shí)才可用。

模塊中的行從 1 開始編號(hào)。例如，讀取 line 和 numlines 參數(shù)值都是 1 的 Lines 屬性時(shí)，Lines 屬性返回的字符串包含模塊中第一行的文本。

要將一行文本插入模塊，請(qǐng)使用 InsertLines 方法。

示例

下面的示例從模塊中刪除指定行：

Function DeleteWholeLine(strModuleName, strText As String) _

     As Boolean

    Dim mdl As Module, lngNumLines As Long

    Dim lngSLine As Long, lngSCol As Long

    Dim lngELine As Long, lngECol As Long

    Dim strTemp As String

    On Error GoTo Error_DeleteWholeLine

    DoCmd.OpenModule strModuleName

    Set mdl = Modules(strModuleName)

    If mdl.Find(strText, lngSLine, lngSCol, lngELine, lngECol) Then

        lngNumLines = Abs(lngELine - lngSLine) + 1

        strTemp = LTrim$(mdl.Lines(lngSLine, lngNumLines))

        strTemp = RTrim$(strTemp)

        If strTemp = strText Then

            mdl.DeleteLines lngSLine, lngNumLines

        Else

            MsgBox "Line contains text in addition to '" _

                & strText & "'."

        End If

    Else

        MsgBox "Text '" & strText & "' not found."

    End If

    DeleteWholeLine = True

Exit_DeleteWholeLine:

    Exit Function

Error_DeleteWholeLine:

    MsgBox Err & " :" & Err.Description

    DeleteWholeLine = False

    Resume Exit_DeleteWholeLine

End Function

可以從以下過程中調(diào)用該函數(shù)，該函數(shù)在模塊 Module1 中搜索常量的聲明語句并將其刪除。

Sub DeletePiConst()

    If DeleteWholeLine("Module1", "Const conPi = 3.14") Then

        Debug.Print "Constant declaration deleted successfully."

    Else

        Debug.Print "Constant declaration not deleted."

    End If

End Sub