NewCurrentDatabase 方法

全部顯示

使用 NewCurrentDatabase 方法可以在 Microsoft Access 窗口中創(chuàng)建一個新的 Microsoft Access 數(shù)據庫 (.mdb)。

expression.NewCurrentDatabase(filepath)

expression    必需。返回“應用于”列表中的一個對象的表達式。

filepath     必需 String 型。字符串表達式，代表新數(shù)據庫文件的名稱，包括路徑名和文件名的后綴。如果網絡支持，也可以按以下形式指定網絡路徑：\\Server\Share\Folder\Filename

注釋  如果未提供文件擴展名，則將 .mdb 追加到文件名中

說明

可以使用該方法通過自動化（以前稱為 OLE 自動化）從控制 Microsoft Access 的其他應用程序中創(chuàng)建一個新的數(shù)據庫。例如，可以從 Microsoft Excel 中使用 NewCurrentDatabase 方法在 Microsoft Access 窗口中新建一個數(shù)據庫。

注釋  使用 NewAccessProject 方法可以在 Access 窗口中創(chuàng)建新的 Microsoft Access 項目 (.adp)。

NewCurrentDatabase 方法用于通過“自動化”從其他應用程序中創(chuàng)建新的 Microsoft Access 數(shù)據庫。從其他應用程序中創(chuàng)建了一個 Microsoft Access 實例后，還必須創(chuàng)建一個新的數(shù)據庫。這個數(shù)據庫在 Microsoft Access 窗口中打開。

如果由 dbname 標識的數(shù)據庫已經存在，則會出現(xiàn)錯誤。

新建數(shù)據庫以 Admin用戶帳戶打開。

示例

下面的示例通過“自動化”從其他應用程序中創(chuàng)建一個新的 Microsoft Access 數(shù)據庫，然后在該數(shù)據庫中創(chuàng)建一個新表。

可以在任何一個可以作為 COM 組件的應用程序的 Visual Basic 模塊中輸入這段代碼。例如，可以從 Microsoft Excel、 Microsoft Visual Basic 或 Microsoft Access 中運行下列代碼。

當指向 Application 對象的變量超出范圍時，它所表示的 Microsoft Access 實例也將關閉。所以，必須在模塊級聲明這個變量。

' Include following in Declarations section of module.

Dim appAccess As Access.Application

Sub NewAccessDatabase()

    Dim dbs As Object, tdf As Object, fld As Variant

    Dim strDB As String

    Const DB_Text As Long = 10

    Const FldLen As Integer = 40

    ' Initialize string to database path.

    strDB = "C:\My Documents\Newdb.mdb"

    ' Create new instance of Microsoft Access.

    Set appAccess = _

        CreateObject("Access.Application.9")

    ' Open database in Microsoft Access window.

    appAccess.NewCurrentDatabase strDB

    ' Get Database object variable.

    Set dbs = appAccess.CurrentDb

    ' Create new table.

    Set tdf = dbs.CreateTableDef("Contacts")

    ' Create field in new table.

    Set fld = tdf. _

        CreateField("CompanyName", DB_Text, FldLen)

    ' Append Field and TableDef objects.

    tdf.Fields.Append fld

    dbs.TableDefs.Append tdf

    Set appAccess = Nothing

End Sub