Office中國論壇/Access中國論壇

標(biāo)題: 尋找表中自動編號字段名函數(shù) [打印本頁]
作者: Henry D. Sy    時間: 2011-12-7 22:14
標(biāo)題: 尋找表中自動編號字段名函數(shù)
  1. '---------------------------------------------------------------------------------------
  2. ' Module    : IsAutoNum
  3. ' DateTime  : 2011-12-07 22:00
  4. ' Author    : Henry D. Sy
  5. ' Purpose   : AutoNumIs("tbl1")
  6. '---------------------------------------------------------------------------------------
  7. Public Function AutoNumIs(ByVal tblName As String) As String
  8.     Dim rs As New ADODB.Recordset
  9.     Dim cnn As New ADODB.Connection
  10.     Dim intCount As Integer
  11.     Dim strName As String
  12.     On Error GoTo AutoNumIs_Error

  14.     Set cnn = CurrentProject.Connection
  15.     rs.Open tblName, cnn, adOpenKeyset, adLockReadOnly
  16.     For intCount = 0 To rs.Fields.Count - 1
  17.         If rs.Fields(intCount).Properties("isautoincrement") Then
  18.             strName = rs.Fields(intCount).Name
  19.             Exit For
  20.         End If
  21.     Next
  22.     If Len(strName) <> 0 Then
  23.         AutoNumIs = strName
  24.     Else
  25.         AutoNumIs = "Not Find"
  26.     End If
  27.     rs.Close
  28.     Set rs = Nothing

  30.     On Error GoTo 0
  31.     Exit Function

  33. AutoNumIs_Error:

  35.     MsgBox "Error " & Err.Number & " (" & Err.Description & ")"
  36. End Function
復(fù)制代碼
作者: 魚兒游游    時間: 2011-12-7 22:35
本帖最后由 魚兒游游 于 2011-12-7 22:58 編輯

斑竹，我試了，發(fā)現(xiàn)有以下問題，能不能再改進一下。
要是當(dāng)前ACCESS數(shù)據(jù)庫，可以取回自動編號的字段。
要是讀取另一個ACCESS數(shù)據(jù)庫（用ADO不用鏈接表）里的數(shù)據(jù)表，則不能取回自動編號的字段。
作者: andymark    時間: 2011-12-8 09:10
把CNN 重設(shè)為打開另一個數(shù)據(jù)庫的連接就行
作者: 魚兒游游    時間: 2011-12-8 12:10
andymark 發(fā)表于 2011-12-8 09:10
把CNN 重設(shè)為打開另一個數(shù)據(jù)庫的連接就行

我試了，不知道為什么不行。
作者: Henry D. Sy    時間: 2011-12-8 12:37
魚兒游游 發(fā)表于 2011-12-7 22:35
斑竹，我試了，發(fā)現(xiàn)有以下問題，能不能再改進一下。
要是當(dāng)前ACCESS數(shù)據(jù)庫，可以取回自動編號的字段。
要 ...
  1. Public Function AutoNumIs(ByVal tblName As String) As String
  2.     Dim rs As New ADODB.Recordset
  3.     Dim cnn As New ADODB.Connection
  4.     Dim intCount As Integer
  5.     Dim strName As String
  6.     On Error GoTo AutoNumIs_Error

  8.     'Set cnn = CurrentProject.Connection
  9.     cnn.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
  10.         CurrentProject.Path & "/ABC.mdb;Jet OLEDB:database password="
  11.     cnn.Open
  12.     rs.Open tblName, cnn, adOpenKeyset, adLockReadOnly
  13.     For intCount = 0 To rs.Fields.Count - 1
  14.         If rs.Fields(intCount).Properties("isautoincrement") Then
  15.             strName = rs.Fields(intCount).Name
  16.             Exit For
  17.         End If
  18.     Next
  19.     If Len(strName) <> 0 Then
  20.         AutoNumIs = strName
  21.     Else
  22.         AutoNumIs = "Not Find"
  23.     End If
  24.     rs.Close
  25.     Set rs = Nothing

  27.     On Error GoTo 0
  28.     Exit Function

  30. AutoNumIs_Error:

  32.     MsgBox "Error " & Err.Number & " (" & Err.Description & ")"
  33. End Function
復(fù)制代碼
abc是你的庫名，保存在一樣的目錄里
作者: 魚兒游游    時間: 2011-12-8 13:14
本帖最后由 魚兒游游 于 2011-12-8 13:21 編輯
Henry D. Sy 發(fā)表于 2011-12-8 12:37
abc是你的庫名，保存在一樣的目錄里


我用你的方法，寫成下面的函數(shù)，但仍然不能取回自動編號字段，不知道錯哪了，幫忙看看，多謝了。
  1. Public Function GetIdentityField(strDatabaseName As String, strPwd As String, strTableName As String) As String
  2. On Error GoTo Err_Handler
  3.     Dim strFieldName As String
  4.     Dim cn           As Object
  5.     Dim rst          As Object
  6.     Dim strConnect   As String
  7.     Dim strSQL       As String
  8.     Dim intCount     As Integer
  9.     strFieldName = ""
  10.     '參數(shù)（數(shù)據(jù)庫名）處理
  11.     If strDatabaseName Like ".\*" Then strDatabaseName = CurrentProject.Path & Mid(strDatabaseName, 2)
  12.     If Not strDatabaseName Like "[A-z]:*" Then strDatabaseName = CurrentProject.Path & "" & strDatabaseName
  13.     '定義ACCESS鏈接串
  14.     strConnect = "Provider=Microsoft.Jet.OLEDB.4.0" & ";Data Source=" & strDatabaseName & ";Jet OLEDB:Database Password=" & strPwd
  15.     '用ADO通過OLEDB直接連接數(shù)據(jù)庫
  16.     Set cn = Nothing
  17.     Set cn = CreateObject("ADODB.Connection")
  18.     With cn
  19.         .ConnectionString = strConnect
  20.         .CursorLocation = adUseClient
  21.         .ConnectionTimeout = 15
  22.         .CommandTimeout = 30
  23.         .Open
  24.     End With
  25.     '打開ADO記錄集
  26.     strSQL = "SELECT * FROM [" & strTableName & "]"
  27.     Set rst = Nothing
  28.     Set rst = CreateObject("ADODB.Recordset")
  29.     With rst
  30.         .Source = strSQL
  31.         .ActiveConnection = cn
  32.         .CursorLocation = adUseClient  '3
  33.         .CursorType = adOpenKeyset
  34.         .LockType = adLockReadOnly
  35.         .Open
  36.     End With
  37.     '查找自動編號字段
  38.     For intCount = 0 To rst.Fields.Count - 1
  39.          If rst.Fields(intCount).Properties("isautoincrement") Then
  40.              strFieldName = rst.Fields(intCount).Name
  41.              Exit For
  42.          End If
  43.     Next
  44.     rst.Close
  45.     cn.Close
  46. Exit_Handler:
  47.     GetIdentityField = strFieldName
  48.     Set rst = Nothing
  49.     Set cn = Nothing
  50.     Exit Function
  51. Err_Handler:
  52.     strFieldName = ""
  53.     MsgBox Err.Description, vbExclamation, "查詢表標(biāo)識列的列名出錯"
  54.     Resume Exit_Handler
  55. End Function
復(fù)制代碼
作者: Henry D. Sy    時間: 2011-12-8 15:21
視乎漏掉最終的賦值
GetIdentityField=strFieldName
作者: 魚兒游游    時間: 2011-12-8 16:12
Henry D. Sy 發(fā)表于 2011-12-8 15:21
視乎漏掉最終的賦值
GetIdentityField=strFieldName

沒有呀
作者: Henry D. Sy    時間: 2011-12-8 17:05
GetIdentityField=strFieldName
rst.Close
cn.Close
作者: 魚兒游游    時間: 2011-12-8 17:27
本帖最后由 魚兒游游 于 2011-12-8 19:19 編輯
Henry D. Sy 發(fā)表于 2011-12-8 17:05
GetIdentityField=strFieldName
rst.Close
cn.Close


關(guān)閉記錄集、關(guān)閉連接不影響strFieldName的值呀。

多謝，斑竹，這問題我解決了，是游標(biāo)的問題。
作者: t小寶    時間: 2011-12-8 19:54
.CursorLocation = adUseClient  '3
這句引起的，也就是不能使用本地游標(biāo)





歡迎光臨 Office中國論壇/Access中國論壇 (http://www.mzhfr.cn/) Powered by Discuz! X3.3